### Ramener plusieurs lignes ayant les mêmes critères de sélection

Problématique :

Mettre en évidence des informations se trouvant dans une base de données (matrice) et répondant à certains critères.

**La difficulté est donc de ramener plusieurs lignes d’informations ayant les mêmes critères de sélection.**

Pour ce faire, il est nécessaire d’utiliser, en les imbriquant, les fonctions suivantes :

**SIERREUR**(**valeur**,**valeur\_si\_erreur**)

**INDEX**(**matrice**;no\_lig;no\_col)

**SI**(**test\_logique**;**valeur\_si\_vrai**;valeur\_si\_faux)

**PETITE.VALEUR**(**matrice**;**k**)

**matrice** représente une matrice ou une plage de données numériques dans laquelle vous recherchez la k-ième plus petite valeur.

**k** représente, dans la matrice ou la plage, le **rang** **de la donnée à renvoyer, déterminé à partir de la valeur la plus petite.**

**LIGNE**(référence)

**référence** est la cellule ou la plage de cellules dont vous voulez obtenir le numéro de ligne.

* Si l'argument référence est omis LIGNE(), la référence par défaut est celle de la cellule dans laquelle la fonction LIGNE apparaît.
* **Si l’argument référence est une plage de cellules et si la fonction LIGNE est entrée sous forme de** **matrice (matrice : permet de créer des formules uniques permettant d'obtenir plusieurs résultats et qui agissent sur un groupe d'arguments répartis dans des lignes et des colonnes. Une plage matricielle partage une même formule tandis qu'une constante matricielle est un groupe de constantes qui sert d'argument.)** **verticale, la fonction LIGNE renvoie les numéros de ligne de la référence sous forme de matrice verticale**.
* L'argument référence ne peut pas faire référence à des zones multiples.

**LIGNES**(**référence**) : **attention au S !**

**référence** est une matrice, une formule matricielle (formule matricielle : formule qui effectue plusieurs calculs sur un ou plusieurs ensembles de valeurs et qui renvoie un ou plusieurs résultats. Les formules matricielles sont placées entre accolades { } et sont entrées en appuyant sur Ctrl+Maj+Entrée.) ou la référence d’une plage de cellules dont vous voulez obtenir le **nombre de lignes**.

**Imbrication :**

SIERREUR(INDEX(matrice;PETITE.VALEUR(SI(plage1=REFERENCE;LIGNE($2:$même nbre ligne que plage));LIGNES($1:1));num.colonne) ; "")

**Logique :**

Il s’agit de rechercher dans une matrice la cellule correspondant au croisement de :

* la ligne égale à la Nième plus petite valeur pour autant que la plage 1 est égale à une référence
* une colonne.

Grâce à la formule matricielle (**introduite en combinant CTRL/MAJ/ENTER**), Excel va projeter virtuellement les matrices et déterminer le rang donc la ligne à utiliser et **cela en fonction de la ligne et de la colonne où la formule se trouve.**

**A noter : généralement une formule matricielle est introduite elle-même dans une plage de cellules. Il faut donc la dupliquer. Pour ce faire, la procédure est la suivante :**

* **introduire la formule dans la première cellule dans le coin supérieur gauche de la plage qui va contenir la même formule et mettre au point la formule**
* **Quand la formule est au point (généralement après quelques essais), on édite la formule (utilisation de la touche F2) et on entre la formule par CTRL/MAJ/ENTER)**
* **On duplique par tirage cette cellule dans toutes les cellules de la plage désirée.**

**Exemple :**

Une matrice **$A$1 :$AO$254** : cette matrice contient 1 ligne titre et 253 lignes de données. A noter que la matrice est « figée » par les $ et sera donc identique sur toutes les lignes où la formule sera copiée.

Dans cette matrice, la colonne **Y** contient l’élément à tester pour la recherche (disons le numéro de facture et plusieurs lignes peuvent contenir le même numéro de facture)

L’onglet qui va effectuer la recherche contient :

* 1 ligne technique (la ligne 1) qui va permettre à la formule de déterminer la colonne (voir plus loin)
* 1 ligne Paramètre (ligne 2) qui permet à l’utilisateur de préciser le numéro de facture désiré (**référence $C$2**)
* 1 ligne Titres (pour déterminer le nom de chaque colonne)
* 30 lignes qui vont contenir la formule permettant d’afficher les informations désirées (30 étant, dans l’exemple, considéré par l’utilisateur comme le nombre de lignes maximum pouvant répondre aux critères demandés)

Comme 30 est un maximum, il est évident que dans beaucoup de cas, il y aura moins de 30 lignes utilisées, il faut donc que ces lignes soient mise à « blanc » soit "". La formule commence donc par un test permettant de mettre à blanc toutes les lignes excédentaires c.à.d. provoquant une erreur.

SIERREUR(……… ; "")

Ensuite nous déterminons la matrice de recherche avec la fonction INDEX :

INDEX(**$A$1 :$AO$254 ;N.ligne ;N.colonne)**

**Il nous faut maintenant déterminer la ligne en utilisant la combinaison des 3 fonctions PETITE.VALEUR ; SI et LIGNE**

PETITE.VALEUR(SI($Y$2:$Y$254 =$C$2;LIGNE($2:$254));LIGNES($1:1))

Grâce à la formule matricielle, Excel va projeter la plage $Y$2 :$Y$254 avec toutes ses valeurs et tester (avec la fonction SI si il y a des valeurs qui correspondent à la demande se trouvant en $C$2. Il va alors transformer la plage valeur en plage VRAI(il y a une valeur qui correspond) / FAUX (il n’y a pas de valeur qui correspond). Ensuite il va projeter une plage virtuelle LIGNE($2 :$254) (2 ; 3 ; 4 ; 5 … ;254) et va déterminer dans cette plage les valeurs qui correspondent à VRAI dans la plage $Y$2 :$Y$254. IL FAUT NATURELLEMENT QUE LES 2 PLAGES COMPORTENT EXACTEMENT LE MEME NOMBRE DE LIGNES). Il obtiendra, par exemple 2 ; 5 ; 8. Cela veut dire que nous savons maintenant qu’il y a 3 lignes qui contiennent le numéro de facture désirée et quelles se trouvent dans les lignes 2 ; 5 ; 8 de la matrice **$A$1 :$AO$254**

C’est maintenant que la fonction PETITE.VALEUR va intervenir car on lui demande de prendre la Nème plus petite valeur que l’on trouve en fonction de la ligne où on se trouve par la fonction LIGNES($1 :1). En effet, on remarquera que cette fonction (qui compte le nombre de ligne de la plage) est paramétrée avec une plage dont la première référence est fixe $1 MAIS LA 2ème REFERENCE EST VARIABLE EN FONCTION DE L’AVANCEMENT DANS LES LIGNES. Donc au fur et à mesure cette fonction va compter le nombre de ligne en augmentant de 1 à chaque ligne et donc demander la 1ère puis 2éme puis 3ème … Nème plus petite valeur… et donc sur la première ligne de recherche elle ira chercher la ligne 2 puis sur la seconde ligne de recherche la ligne 5 puis la ligne 8. Toutes les autres lignes seront négligées ou mises à blanc par la fonction SIERREUR.

**Il est fortement conseillé de visualiser cette progression de la formule grâce au bouton « Evaluation de formules**



**Maintenant que nous avons la ligne, il reste maintenant à déterminer la colonne dans la matrice $A$1 :$AO$254.**

**Pour déterminer la colonne, il y a différentes méthodes :**

* En « dur » c.à.d. on précise dans la formule le numéro de la colonne (on ne met pas la lettre mais bien le numéro de la colonne). Cette méthode a le gros inconvénient de rendre la formule non copiable horizontalement car il faut chaque fois adapter le numéro de la colonne ;
* Si les colonnes réceptrices sont dans le même ordre ET contigües à la plage émettrice, on peut s’appuyer sur la numérotation des colonnes réceptrice en corrigeant éventuellement un décalage. Ainsi si la plage émettrice contient des informations à ramener à partir de la colonne F (6ème colonne) et que dans la plage réceptrice on commence par la colonne A (1ère colonne) on peut trouver le numéro de colonne par la formule : COLONNE()+5 soit 1+5 = 6. Quant on duplique la formule horizontalement, la colonne deviendra 7 puis 8 puis….
* Enfin, et c’est le cas dans notre exemple, les colonnes émettrices et réceptrices sont dans un ordre différent ou non contigües, il y a une dernière technique qui consiste à créer une ligne « technique » (ici la ligne 1 que nous allons masquer car d’aucun intérêt pour l’utilisateur) qui permet d’encoder les numéros des colonnes désirées horizontalement UNE SEULE FOIS et donc de pouvoir dupliquer la formule dans toute sa plage. Il faut, bien entendu, figer la ligne de cette référence à l’aide du $ (B$1 par exemple). A noter que la lettre B n’est pas précédée du $ et évoluera donc lors de la duplication.

Nous avons donc déterminé la ligne et la colonne qui permet d’afficher la cellule correspondante dans la matrice **$A$1 :$AO$254 et donc la plage réceptrice contiendra uniquement les lignes répondant au critère demandé (numéro de facture).**

**A noter que l’on peut naturellement adapter cette formule en augmentant le nombre de critères par exemple en remplaçant la fonction SI par la fonction ET ou plusieurs fonctions SI imbriquées.**

**Il me reste à vous souhaiter BON COURAGE et à vous conseiller l’absorption de 3 aspirines pour faire passer la migraine…**

**NB : les couleurs dans le texte sont censés aider à la compréhension en situant le sujet traité dans la formule où les segments ont été mis dans la même couleur.**